Flash Blog

Flash Decompiler Trillix

Horatiu Condrea — Fri, 14 May 2010 17:55:27 +0000

A few days ago, I came across a software which I found quite interesting. Flash Decompiler Trillix is a SWF to FLA converter. So far I have not used any kind of Flash Decompiler, but this software reproduce a very good ActionScript code. Well, I said the code is good, not ideal. Is perfect to reproduce your FLA for small projects, if your computer crash and damage the FLA file, but the SWF is still ok, also is able to restore your original Flex source.

What I think is interesting is that you can edit the SWF file directly from your Flash Decompiler Trillix without knowing codeing. Is true that you can’t do to much with the edit tools, but is enough to get around and make some changes.

What is again very useful, is that you can extract SWF elements such: Flash Video to AVI, MPEG, FLV and FLA, save sounds as WAV or MP3, images – as PNG, JPEG and BMP, texts as RTF, TXT and HTML.

The software design is simple and you can easy see the tools.

And last, but not least you can capture SWF movies from the Internet with Flash Decompiler! Save Flash Movie, have 2 web plug-ins for Internet Explorer and FireFox. So, if you want to save a flash movie to your hard disk from the internet, you can do that . And after that if you want you can edit the Flash movie, with the edit tools.

And now this is the full features list:

* Full support of Flash 5, 6, 7, 8, 9 and 10 including AS 2.0 and 3.0
* Extract all Flash file resources into various formats
* Support of SWF files built in Flex (v2 and v3 supported)
* Extract Flash video into AVI, MPEG and other playable formats
* Batch decompilation and conversion of Flash movies
* Edit more Flash objects now without converting to FLA: images, texts, hyperlinks, sounds, colors and lines
* New scalable shining interface with ribbon bar
* Advanced built-in Flash player to preview and playback your Flash movies
* ASCII, Hex, Pi-code and common ActionScripts representation (not in AS 3.0)
* Detailed configuration of SWF to FLA conversion (motion tweens, library, FLA format, AS and other settings)
* Take screenshots of Flash file played
* Unique global ActionScripts search in all tasks simultaneously
* Simple and effective adding of multiple files or folders to the Tasks list
* Easily change the background color of any SWF file
* Detailed tag information panel
* Save Flash Movie in Internet Explorer and FireFox plug-ins are supplied for simple saving of SWF movies online
* The software is digitally signed to verify Eltima quality and software authenticity
* Many other convenient features for professional Flash decompilation

If you think, you need such a software visit Flash Decompiler Trillix page.

XML Video Player (AS 3.0)

Horatiu Condrea — Fri, 12 Mar 2010 10:23:24 +0000

Here is a new flash component you can see it here: XML Video Player

Description:

This player can be set to any size you want by changing the player width and height

It plays any kind of video file that Flash Player supports ( FLV / H.264 encoded video including MP4, M4V, M4A, MOV, Mp4v, F4V).

To be able to play H.264 video you need Player 9.0.115.0 or later.

The entire graphic is in one MovieClip so it is easy to change the skin in case you need to adapt the graphic design of this Video Player

Features ::

- XML driven content
- Video streaming with buffer
- Full screen video mode supported
- Unlimited amount of videos an be displayed
- Play
- Pause
- Scrollable seek bar
- FLV time duration
- FLV Title
- Volume Control
- Fullscreen (just a click)

Professional XML MP3 Player

Horatiu Condrea — Wed, 24 Feb 2010 15:48:29 +0000

Here is a new flash component you can see it here: Profesional XML Mp3 Player

And a short description:

Features:

- Play Button

- Pause Button;

- Prev Button;

- Next Button;

- Current time and Total Time;

- Volume Bar;

- Name of the current MP3 file that is playing;

- Album Cover.

-Unlimited number of MP3 files.

XML settings:

- artist_name – the artist name

- song_title – the song tile

- image_path – the image path for each song

- mp3_path – the path for each .mp3 file

Flash Scope

Horatiu Condrea — Sat, 06 Feb 2010 19:22:21 +0000

A few days ago, I found a website that I think has all the qualities to become one of the most popular sites in the area -buy and sell flash components-. I will not say more, take a look and tell me what you think.

WebSite:http://flashscope.com

AS 3.0 Augmented Reality with Blender and PV3D

Horatiu Condrea — Thu, 10 Dec 2009 18:12:56 +0000

Introduction

In this tutorial you will learn how to create a simple AR(Augmented Reality) scene, at first appearance this code is a little hairy but you don’t have to understand every part of it to use it.

Requirements

1. Web Camera

Pre-Requesites

It would be useful for you if you are familiar with PV3D. It would be good to know 3d modeling with Blender and other 3d modeling program

Save a Pattern

First of all, this is not a tutorial for beginers, but I will try to explain very well all the steps that must be taken to obtain the final result.

Well, download the Marker File. You will see a AIR file, this AIR file will help ous to save a pattern for our Augmented Reality project. Instal the Marker File…on the desktop you will see a ARToolKit Marker Generator AIR file.

Open it, in the same time you Web Camera will start, than you need to save a pattern, you will see a button named Save Pattern and same red lines walking there, those lines will try to find a pattern. Well, now you need to show a paper with a pattern.

A exemple of pattern:

While, you show the paper, on the camera you will see that the red linis are around the pattern.Like in this picture:

In that moment click the save button and save the pattern. In this tutorial my pattern is named pattern.pat.

That was the first step.

3D Model

For designers, this is maybe the most important step, but I’m not a designer ao something like that. I’m only a ActionScript developer, and I will analyze the step from my point of view. For this step you can use Blender, Swift 3D or another modeling program, but unse only the program able to export in Collada. First if you are a beginer in 3d (like me), you can draw a cube or something. If you are use Blender, and have already the made 3d model. Go to File->Export->Collada 1.4(dae).

After exporting you will have a file named something.dae. This file contains our 3d model that we use in PV3D.

If you are useing Swift 3D, the first thing again is draw you model, and export to PV3D. In Swift 3D, we use other option caled Export Selected object To Papervision3D…. Like in this picture:

After that you will have a .swf file , a .fla file, and the most important thing a .dae file. Well now we have the pattern and the 3d model. Is time to do same develop work with ActionScript 3.0 .

Final step 2

Make a new project

If you use Flex Builder just create a new ActionScript 3.0 Project and called augmentedReality. If you unse Flash CS3 or CS4 create a Flash File(ActionScript 3.0), you can give what name you want. At this file create a class called augmentedReality.as. The Flash File and the class must be in the same folder.

For Flex:

And if you are useing flash, there is a simple pictutre to help you:

Well, now we are ready to write the code.

Final step 3.

Start to write the code

package
{
	import flash.display.Sprite;
 
	public class augmentedReality extends Sprite
	{
		public function augmentedReality()
		{
 
		}
	}
}

Here we have the augmentedReality class copy this in Flash, if you are useing flash.

Same imports thing

 
package
{
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.utils.ByteArray;
 
    import org.libspark.flartoolkit.core.FLARCode;
    import org.libspark.flartoolkit.core.param.FLARParam;
    import org.libspark.flartoolkit.core.raster.rgb.FLARRgbRaster_BitmapData;
    import org.libspark.flartoolkit.core.transmat.FLARTransMatResult;
    import org.libspark.flartoolkit.detector.FLARSingleMarkerDetector;
    import org.libspark.flartoolkit.pv3d.FLARBaseNode;
    import org.libspark.flartoolkit.pv3d.FLARCamera3D;
    import org.papervision3d.objects.parsers.Collada;
    import org.papervision3d.render.BasicRenderEngine;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.view.Viewport3D;
 
    [SWF(width="640", height="480", frameRate="30", backgroundColor="#FFFFFF")]
 
    public class augmentedReality extends Sprite
    {
         public function augmentedReality()
	   {
 
         }
     }
}

Well, here we need the Papervision 3d library, and the Augmented Reality library.

Private Variables and Embled files

Now we need to embled the pattern and a most important file the camera_para.dat This file is in the Augmented Reality lib . You don’t need to know want is in this file just embled this file.

package
{
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.utils.ByteArray;
 
    import org.libspark.flartoolkit.core.FLARCode;
    import org.libspark.flartoolkit.core.param.FLARParam;
    import org.libspark.flartoolkit.core.raster.rgb.FLARRgbRaster_BitmapData;
    import org.libspark.flartoolkit.core.transmat.FLARTransMatResult;
    import org.libspark.flartoolkit.detector.FLARSingleMarkerDetector;
    import org.libspark.flartoolkit.pv3d.FLARBaseNode;
    import org.libspark.flartoolkit.pv3d.FLARCamera3D;
    import org.papervision3d.objects.parsers.Collada;
    import org.papervision3d.render.BasicRenderEngine;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.view.Viewport3D;
 
    [SWF(width="640", height="480", frameRate="30", backgroundColor="#FFFFFF")]
 
	public class augmentedReality extends Sprite
	{
		[Embed(source="pattern.pat", mimeType="application/octet-stream")]
		private var pattern:Class;
 
		[Embed(source="camera_para.dat", mimeType="application/octet-stream")]
		private var params:Class;
 
		private var FlarParams:FLARParam;
		private var FlarCode:FLARCode;
		private var vid:Video;
		private var camera:Camera;
		private var FlarCamera:FLARCamera3D;
		private var bmd:BitmapData;
		private var FlarRaster:FLARRgbRaster_BitmapData;
		private var FlarDetector:FLARSingleMarkerDetector;
		private var container:FLARBaseNode;
		private var viewPort:Viewport3D;
		private var scene:Scene3D;
		private var renderEngine:BasicRenderEngine;
		private var TransMatResult:FLARTransMatResult;
 
            public function augmentedReality()
		{
			setFLAR();
			setCamera();
			setBitmap();
			setPV3D();
			addEventListener(Event.ENTER_FRAME, loop);
		}
     }
}

In the constructor we have same function that we will have to explain, in the following steps.

We have the setFLAR(); function. In this function we will load the camera_para, and the pattern.

In the setCamera(); function, we will set the option for the Web Camera.. the resolution, the fps.

Well in the setBitmap(); function, we will do a bitmap data for our FLARRgbRaster_BitmapData. And we will draw the bitmap to the video.

And here at the setPV3D(); function, we will add the 3d model.

Private Methods

            private function setFLAR():void
		{
			FlarParams = new FLARParam();
			FlarParams.loadARParam(new params() as ByteArray);
			FlarCode = new FLARCode(16,16);
			FlarCode.loadARPatt(new pattern());
		}
 
		private function setCamera():void
		{
			vid = new Video(640,480);
			camera = Camera.getCamera();
			camera.setMode(640,480,31);
			vid.attachCamera(camera);
			addChild(vid);
		}
 
		private function setBitmap():void
		{
			bmd = new BitmapData(640,480,true);
			bmd.draw(vid);
			FlarRaster = new FLARRgbRaster_BitmapData(bmd);
			FlarDetector = new FLARSingleMarkerDetector(FlarParams,FlarCode,80);
		}
 
		private function setPV3D():void
		{
			scene = new Scene3D();
			FlarCamera = new FLARCamera3D(FlarParams);
			container = new FLARBaseNode();
			scene.addChild(container);
 
			var obj:Collada = new Collada("tank.dae");
			container.addChild(obj);
 
			renderEngine = new BasicRenderEngine();
			TransMatResult = new FLARTransMatResult();
 
			FlarCamera.z = 0;
 
			viewPort = new Viewport3D();
			addChild(viewPort);
 
			obj.rotationY += 20;
			obj.rotationX += 10;
		}

Well,for a better understanding about this private methods. I will explain again what deals they have.

            private function setFLAR():void
		{
			FlarParams = new FLARParam();
			FlarParams.loadARParam(new params() as ByteArray);
			FlarCode = new FLARCode(16,16);
			FlarCode.loadARPatt(new pattern());
		}

In setFLAR we have a FlarParams instance, and we load the params in this instance. And because the params are a binary file, we load this params as a ByteArray. And in the FLARCode instance we load the pattern file, and give a resolution, in this case 16×16.

private function setCamera():void
		{
			vid = new Video(640,480);
			camera = Camera.getCamera();
			camera.setMode(640,480,31);
			vid.attachCamera(camera);
			addChild(vid);
		}

The setCamera function set up the option for our camera. Well, I set up the resolution 640×480, but if you have a more performance camera, give a larger resolution. And I think 31 fps is good for all kind of camera. And after that we attach the camera on the Video instance. And of course we addChild the vid(Video).

Well, after you set this part of code, if you run you project, ypu will see, samething like that:

And if you click Allow, your camera will start.

private function setBitmap():void
		{
			bmd = new BitmapData(640,480,true);
			bmd.draw(vid);
			FlarRaster = new FLARRgbRaster_BitmapData(bmd);
			FlarDetector = new FLARSingleMarkerDetector(FlarParams,FlarCode,80);
		}

Well, now we have the setBitmap, here we create a BitmapData, give the same resolution as the camera. And we “draw” the vid that contains all the information about our camera.After that we have the FlarRaster and the FlarDetector. Well the FlarDetector, is a detector, which will see the pattern on the stage… 80 reprents the marker width.

private function setPV3D():void
		{
			scene = new Scene3D();
			FlarCamera = new FLARCamera3D(FlarParams);
			container = new FLARBaseNode();
			scene.addChild(container);
 
			var obj:Collada = new Collada("tank.dae");
			container.addChild(obj);
 
			renderEngine = new BasicRenderEngine();
			TransMatResult = new FLARTransMatResult();
 
			FlarCamera.z = 0;
 
			viewPort = new Viewport3D();
			addChild(viewPort);
 
			obj.rotationY += 20;
			obj.rotationX += 10;
		}

And finaly the setPV3D function. In this function I add the 3d model to the FLARBaseNode.

Final Code

package
{
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.utils.ByteArray;
 
    import org.libspark.flartoolkit.core.FLARCode;
    import org.libspark.flartoolkit.core.param.FLARParam;
    import org.libspark.flartoolkit.core.raster.rgb.FLARRgbRaster_BitmapData;
    import org.libspark.flartoolkit.core.transmat.FLARTransMatResult;
    import org.libspark.flartoolkit.detector.FLARSingleMarkerDetector;
    import org.libspark.flartoolkit.pv3d.FLARBaseNode;
    import org.libspark.flartoolkit.pv3d.FLARCamera3D;
    import org.papervision3d.objects.parsers.Collada;
    import org.papervision3d.render.BasicRenderEngine;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.view.Viewport3D;
 
    [SWF(width="640", height="480", frameRate="30", backgroundColor="#FFFFFF")]
 
	public class augmentedReality extends Sprite
	{
		[Embed(source="pattern.pat", mimeType="application/octet-stream")]
		private var pattern:Class;
 
		[Embed(source="camera_para.dat", mimeType="application/octet-stream")]
		private var params:Class;
 
		private var FlarParams:FLARParam;
		private var FlarCode:FLARCode;
		private var vid:Video;
		private var camera:Camera;
		private var FlarCamera:FLARCamera3D;
		private var bmd:BitmapData;
		private var FlarRaster:FLARRgbRaster_BitmapData;
		private var FlarDetector:FLARSingleMarkerDetector;
		private var container:FLARBaseNode;
		private var viewPort:Viewport3D;
		private var scene:Scene3D;
		private var renderEngine:BasicRenderEngine;
		private var TransMatResult:FLARTransMatResult;
 
		public function augmentedReality()
		{
			setFLAR();
			setCamera();
			setBitmap();
			setPV3D();
			addEventListener(Event.ENTER_FRAME, loop);
		}
 
		private function setFLAR():void
		{
			FlarParams = new FLARParam();
			FlarParams.loadARParam(new params() as ByteArray);
			FlarCode = new FLARCode(16,16);
			FlarCode.loadARPatt(new pattern());
		}
 
		private function setCamera():void
		{
			vid = new Video(640,480);
			camera = Camera.getCamera();
			camera.setMode(640,480,31);
			vid.attachCamera(camera);
			addChild(vid);
		}
 
		private function setBitmap():void
		{
			bmd = new BitmapData(640,480,true);
			bmd.draw(vid);
			FlarRaster = new FLARRgbRaster_BitmapData(bmd);
			FlarDetector = new FLARSingleMarkerDetector(FlarParams,FlarCode,80);
		}
 
		private function setPV3D():void
		{
			scene = new Scene3D();
			FlarCamera = new FLARCamera3D(FlarParams);
			container = new FLARBaseNode();
			scene.addChild(container);
 
			var obj:Collada = new Collada("tank.dae");
			container.addChild(obj);
 
			renderEngine = new BasicRenderEngine();
			TransMatResult = new FLARTransMatResult();
 
			FlarCamera.z = 0;
 
			viewPort = new Viewport3D();
			addChild(viewPort);
 
			obj.rotationY += 20;
			obj.rotationX += 10;
		}
 
		private function loop(e:Event):void
		{
			bmd.draw(vid);
 
			try
			{
				if(FlarDetector.detectMarkerLite(FlarRaster, 80) &#038;& FlarDetector.getConfidence() > 0.5)
				{
					FlarDetector.getTransformMatrix(TransMatResult);
					container.setTransformMatrix(TransMatResult);
					renderEngine.renderScene(scene, FlarCamera, viewPort);
				}
			}
 
			catch(e:Error){}
		}
	}
}

And the final result must be something like that,my 3d model is a thank, and look how he is:

That was the Augmented Reality tutorial.

Cya next time

A new blog

Horatiu Condrea — Mon, 16 Nov 2009 18:43:03 +0000

Well, today I start a new blog. This is a blog in Romanian, who is interested in my opinion, can access my other blog here: http://misk.flashdesign-store.com/. So… have a good time reading my blogs.

Accessing the contents of a folder

Horatiu Condrea — Mon, 05 Oct 2009 17:10:57 +0000

AIR allows you to obtain a list of files and folders in a particular folder. This can be very useful if, for example, you want to create an application to load and display all images in a given folder. For each file and folder, you can also access detailed information such as the size, the extension (if it’s a file), the remaining disk room, the creation date, and so on.To access the list of files and documents in a folder, you have to use the getDirectoryListing() function provided by the File class. This method returns a list of File objects contained in the relevant folder.

In this exemple I will use a “DataGrid” to be easy to see what we have in the folder, a “TextArea” to see the location of the folder, and of course a button. Well, this is code:

package 
{
	import fl.controls.Button;
	import fl.controls.DataGrid;
	import fl.controls.TextArea;
	import fl.controls.dataGridClasses.DataGridColumn;
	import fl.data.DataProvider;
 
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.filesystem.File;
 
	public class Main extends MovieClip
	{
 
		public var choose:Button;
		public var output:TextArea;
		public var directoryList:DataGrid;
 
		private var folder:File;
 
		public function Main()
		{
			super();
 
			choose.addEventListener( MouseEvent.CLICK, showDirectorySelection );
 
			var col1:DataGridColumn = new DataGridColumn();
			var col2:DataGridColumn = new DataGridColumn();
			var col3:DataGridColumn = new DataGridColumn();
			var col4:DataGridColumn = new DataGridColumn();
 
			col1.headerText = "File name";
			col1.dataField = "name";
			directoryList.addColumn( col1 );
 
			col2.headerText = "File size";
			col2.dataField = "size";
			directoryList.addColumn( col2 );
 
			col3.headerText = "File extension";
			col3.dataField = "extension";
			directoryList.addColumn( col3 );
 
			col4.headerText = "Creation date";
			col4.dataField = "creationDate";
			directoryList.addColumn( col4 );
		}
 
		private function showDirectorySelection( event:MouseEvent ):void
		{
			folder = new File();
 
			folder.addEventListener( Event.SELECT, directorySelected );
			folder.browseForDirectory("Choose a directory on your system");
		}
 
		private function directorySelected( event:Event ):void
		{
 
			output.appendText("Selected folder: "+folder.nativePath+"\n");
 
			var directoryContents:Array = folder.getDirectoryListing();
			var dp:DataProvider = new DataProvider();
			var folderNum:int = -1;
			var item:File;
 
			for each( item in directoryContents )
			{
				if( item.isDirectory )
				{
					folderNum++;
					dp.addItemAt( item, folderNum );
				}
 
				else
				{
					dp.addItem( item );
				}
			}
 
		directoryList.dataProvider = dp;
		}
	} 
}

And you can download the final AIR file by here: Accessing the contents of a folder

AS 3.0 Stage Align

Horatiu Condrea — Wed, 26 Aug 2009 13:03:19 +0000

Just a simple AS 3.0 Stage Align with Tween Little. Here you can see the component:http://www.flashcomponents.net/component/as_3.0_stage_align.html
And if you find this component useful for you, buy it.

Here you can see the swf file:

Simple 3D Carousel AS 3.0

Horatiu Condrea — Fri, 14 Aug 2009 15:38:54 +0000

As the title says, this is a simple 3D Carousel AS 3.0. XML driven images, easy to implement in your Flash projects. You can buy or see the demo here: http://www.flashcomponents.net/component/simple_3d_carousel_as_3.0.html

I do not want to come up with accurate descriptions, If you like it, buy it.

Cya, next time.

AS 3.0 Simple PreLoader

Horatiu Condrea — Tue, 23 Jun 2009 12:58:01 +0000

Well, because I need to live me too, I make a simple AS 3.0 PreLoader, and it is put on the FlashComponents, if you want to buy click here: Click

Here is the demo: